Fonction pratique dans Excel : NB.SI

Il faut aller au-delà de la saisie manuelle d’un tableau Excel pour comprendre tout ce que le logiciel a à offrir. Grâce aux nombreuses fonctions utiles que propose Microsoft, vous pouvez grandement faciliter votre travail, tant pour votre utilisation privée que professionnelle. Cependant, pour profiter des avantages qu’offrent les feuilles de calcul, il est bon de connaître quelques fonctions pratiques. La fonction NB.SI (en anglais COUNTIF) en fait partie. Découvrez pourquoi cette fonction est incontournable et comment l’utiliser correctement.

A quoi sert la fonction NB.SI ?

Imaginez que vous ayez une liste d’entrées non triées. Par exemple, la liste des ventes des derniers mois. Vous voulez savoir combien de fois un article particulier a été vendu. Au lieu de parcourir toute la liste à la main, vous pouvez utiliser la fonction NB.SI. Elle compte ainsi automatiquement le nombre de fois où une certaine valeur s’applique.

Dans Excel, NB.SI est une fonction de statistique. Pour reprendre notre exemple, vous pouvez vous demander combien de fois l’article XY a été vendu. En appliquant la formule à chaque produit disponible, vous pouvez savoir quel article est le plus populaire. Les données statistiques peuvent ensuite être utilisées pour créer des graphiques.

La fonction NB.SI est tout simplement une combinaison de la fonction SI (qui pose des conditions / fonction logique) et de NB (qui compte des occurrences / fonction logique). Cela aboutit à ce qu’Excel ne compte une cellule que si une certaine valeur est remplie.

Ne pas confondre NB.SI avec SOMME.SI : la dernière n’affiche pas le nombre de valeurs dans une zone de données, mais additionne directement les quantités. Dans notre exemple : un article est vendu en plusieurs quantités à chaque action commerciale. SOMME.SI détermine combien d’unités de produits ont finalement été vendus.

Utilisation de NB.SI. Comment faire ?

Pour les fonctions Excel, il est important d’utiliser la bonne syntaxe :

                =NB.SI(zone d’application;critère de recherche)

L’expression « zone d’application » fait référence aux cellules de votre tableau que vous voulez intégrer au comptage. Le « critère de recherche » spécifie quant à lui la valeur à prendre en compte.

Dans la zone d’application, il est nécessaire d’entrer la plage de votre tableau avec un point de départ et un point d’arrivée (séparés par deux points). On entrera par exemple « B3:B14 » pour intégrer la plage comprise dans cette zone, ainsi que les deux cellules de début et de fin mentionnées. Pour votre sélection, Excel donne également la possibilité de faire glisser des zones à l’aide de la souris. Les plages de cellules intégrées sont alors affichées en surbrillance. Il est aussi possible de sélectionner une colonne complète, par exemple avec : « B:B ». Naturellement, cela fonctionne de la même manière avec les lignes.

Vous pouvez saisir comme critère de recherche une valeur, à mettre ensuite entre guillemets (par exemple, « Chaussures ») ou en vous référant à une cellule dans laquelle se trouve cette valeur (par exemple, B3). Les deux données (zone d’application et critère de recherche) sont séparées par un point-virgule. Il n’y a pas d’espace dans la syntaxe.

                =NB.SI(B3:B14;"Chaussures")

                = NB.SI (B3:B14;F3)

Remarque

Les fonctions sont toujours introduites dans Excel avec un signe égal. Sinon, le programme interprète l’entrée comme une simple chaîne de caractères et l’écrit simplement dans la cellule.

Excel a également une fonction d’auto-complétion pratique. Pour ce faire, faites glisser la fonction (grâce à la petite croix en bas à droite de la cellule activée) sur les lignes du dessous : ces dernières appliquent alors la formule et ajustent automatiquement la zone d’application et le critère de recherche. En effet, la fonction va se référer automatiquement aux cellules une ligne plus bas. Si vous ne le souhaitez pas, par exemple parce que vous voulez que la zone de recherche reste la même, vous pouvez saisir ces valeurs comme valeurs absolues. Il suffit pour cela d’insérer le signe dollar « $ » comme suit :

                =NB.SI($B$3:$B$14;F3)

NB.SI dispose également d’une fonction avancée appelée NB.SI.ENS. Elle permet d’insérer plusieurs zones d’application et plusieurs critères de recherche dans votre fonction. Par exemple, si vous voulez compter les ventes de chaussures mais uniquement lorsque ces dernières ce sont vendues plus d’une fois :

=NB.SI.ENS(B3:B14;$G4;C3:C14;>1)

Remarque

La fonction NB.SI traite indifféremment les minuscules et majuscules.

La fonction NB.SI expliquée à l’aide d’exemples

Supposons que vous ayez un magasin de détail et que, pour vos statistiques, vous vouliez savoir parmi vos acheteurs combien viennent directement de la même ville que votre boutique. Vous avez demandé à tous les clients s’ils acceptaient de vous donner leur code postal. Les données sont saisies dans un tableur. Maintenant, vous pouvez compter les cellules qui contiennent le code postal de votre boutique.

                =NB.SI(B3:B17;"10969")

Conseil

Dans cet exemple, nous utilisons les nombres comme texte (le code postal). Cela ne fait aucune différence pour la fonction NB.SI, mais pour éviter des problèmes éventuels dans d’autres situations, il est conseillé de formater les cellules en texte.

De cette façon, vous pouvez savoir combien de clients habitent directement dans la même ville que votre magasin. Si vous voulez aussi savoir le contraire, c’est-à-dire quels sont les clients qui viennent d’une zone en dehors de votre ville, il est nécessaire de mettre un signe inférieur (<) et supérieur (>) devant le critère de recherche.

                =NB.SI(B3:B17;"<>10969")

Si vous ne voulez pas entrer la valeur directement (ici le code postal) mais vous voulez faire référence à la valeur en mentionnant une cellule, vous devez entourer la négation par des guillemets ("<>") et la lier à la cellule avec l’esperluette (&) :

                =NB.SI(B3:B17;"<>"&B4)

Par ailleurs, vous avez également interrogé les clients sur leur âge et saisi ces chiffres en prenant en compte les codes postaux respectifs. Vous supposez que votre offre s’adresse principalement aux personnes de plus de 50 ans. Pour vérifier cette hypothèse, vous pouvez utiliser la fonction NB.SI. Puisque vous voulez inclure non seulement tous les acheteurs de plus de 50 ans, mais aussi ceux qui ont exactement 50 ans, la fonction doit contenir une valeur supérieure et égale :

                =NB.SI(C3:C17; ">=50")

Bien entendu, le résultat inverse vous intéresse également, c’est-à-dire le nombre de clients de moins de 50 ans. Dans ce cas, vous n’avez pas besoin d’une négation : le signe inférieur est suffisant.

                =NB.SI(C3:C17; "<50")

Si une personne ne vous a pas donné d’âge, la case vide est simplement déduite des résultats. Si l’on supprime un code postal qui n’est pas égal à 10969 en revanche, on remarque qu’il n’en découle aucun changement dans les premières formules effectuées. Vous pouvez donc améliorer votre formule, en soustrayant le nombre de cellules vides à votre résultat premier. Pour indiquer à Excel que vous voulez utiliser les cellules vides comme critères de recherche, utilisez les guillemets comme suit :

                =NB.SI(B3:B17;"<>10969")-NB.SI(B3:B17;"")

Vous pouvez également utiliser la fonction NB.SI.ENS à ce stade. Pour ce faire, ajoutez un autre critère de recherche à votre formule initiale, à savoir que les cellules vides ne doivent pas être ajoutées. La formule ne soustrait donc pas les cellules vides, mais les excluent des statistiques :

                =NB.SI.ENS(B3:B17;"<>10969";B3:B17;"<>")

Enfin, si vous voulez savoir combien de clients de plus de 50 ans habitent dans la même ville que votre boutique, vous pouvez également utiliser la fonction NB.SI.ENS. Pour ce faire, insérez le critère supplémentaire dans la formule :

                =NB.SI.ENS(B3:B17;"10969";B3:B17;"<>";C3:C17;">=50")

Remarque

Excel a des difficultés avec les longues chaînes de caractères pour NB.SI. Si vous souhaitez utiliser des critères de recherche de plus de 255 caractères, il est recommandé d’enchaîner les critères à l’aide de l’esperluette « & » : =NB.SI(B3:B17;"109"&"69").

Lors de votre enquête, vous avez en outre noté ce que les clients avaient acheté. En tant que propriétaire d’un magasin de chaussures, vous vous intéressez à la vente de ces produits uniquement, et non les lacets ou autres articles annexes. Pour prendre en compte les « chaussures pour enfants » comme les « chaussures pour femmes » et autres chaussures, vous pouvez utiliser un caractère de remplissage, qui est ici représenté par un astérisque (*) :

=NB.SI(D3:D17;"Chaussures*")

Remarque

Les caractères de remplissages ne fonctionnent que pour la saisie de texte. Cela ne vaut pas pour les valeurs numériques par exemple ou pour les points d’interrogation (?). Si vous voulez vraiment compter les points d’interrogation dans vos colonnes ou un astérisque, utilisez plutôt un tilde (~) avant ces derniers ("~*").